NativeWindowを仮想デスクトップ一杯にして、そのステージ上をキャラが動きまわれるようにしたかったんです。
それで、デュアルモニターなんかを考慮した仮想デスクトップの計算方法が書いてあり、そこまでは大喜び！

> 仮想デスクトップのサイズ計算

これすごいですよ。あるモニタ（Screen）の横にさらにモニタがあるかどうかの判定方法なんかも書いてあっておお！みたいな。
まあ、そこまではいいです。
問題は、これを参考に

		private function setStageSettings():void
		{
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			var virtualRect:Rectangle = computeVirtualBounds(Screen.screens);
			stage.nativeWindow.width = virtualRect.width;
			stage.nativeWindow.height = virtualRect.height;
			stage.nativeWindow.x = 0;
			stage.nativeWindow.y = 0;
		}

		private function computeVirtualBounds(screens:Array):Rectangle{
			var bounds:Rectangle = new Rectangle();
			for each (var screen:Screen in screens){
				if(bounds.left > screen.bounds.left){bounds.left = screen.bounds.left;}
				if(bounds.right < screen.bounds.right){bounds.right = screen.bounds.right;}
				if(bounds.top > screen.bounds.top){bounds.top = screen.bounds.top;}
				if(bounds.bottom < screen.bounds.bottom){bounds.bottom = screen.bounds.bottom;}
			}
			return bounds;
		}

とかやってみたんですよ。そしたらWin7のOSのタスクバー（アプリきりかえられる部分）の上にNativeWindowがのっかる！！！
通常はAIRに限らずどんなアプリでもタスクバーの下というか裏側にくるんですが、それがなぜか表側にきちゃって
操作ができなくなっちゃうんですよ！

それでですね、ネットとか公式サイトとか説明書とか探したんだけど結局わからず、
自分で地道に調べた結果やっとわかった結論としては
・ある一定の大きさ以上の幅・高さである（少なくとも１画面分以上）
・nativeWindowのx=0,y=0である
っていう２つの条件がそろうとダメっぽい。なんだそりゃ、そんなのわかんないよー。

なので、幅と高さを仮想デスクトップからそれぞれ2pxずつひいて、
x=1,y=1とかやったら大丈夫になりました。

この挙動すごーくあやしいので、ひょっとしたら私の端末だけかもしれないです。
一応書いておくと Win7 64bit proffesional です。
特にGPUを使うとかそういうことはしてません。なんなんだろー。

同期処理の方の読み取りは比較的スムーズにできたのですが、
非同期処理で同じようにしようと思ったら全くできなかったのでメモです。

>> 読み取りバッファと FileStream オブジェクトの bytesAvailable プロパティ

なんか、まとめると
・同期処理中はファイルのすべてのバイトが読み取り可能
・非同期処理中はprogress イベント中に全バイトの一部のみが可能。progressイベントがすすむと一度たくわえられたバイトは削除されて、次の範囲のバイト列を読み取れるようになる。

って感じでしょうかね。
今調べてるのは、短いテキストファイルの読み書きをしようと思ってるだけなので、今回は同期処理でやってしまおうと思いますけど、重いデータとか扱うときは非同期処理になると思うので面倒くさそうだなー。

Win7のFile.applicationStorageDirectoryのありか

Macは調べてないです。すみません。
C:\Users\{ ユーザー名 }\AppData\Roaming\com.adobe.example.Hoge\Local Store
みたいなところ。

AIRのいけないところはアンインストールしてもここのデータは残りっぱなしだってことかな。

あと、絶対にインストーラー通さないとアプリとして実行できないところ。
Flashってお遊びアプリみたいの作るのと相性がいいから、絶対にインストーラー通さないといけないのって
ツラいところだと思う。お手軽感がないっていうか。

例えば、スロットアプリを作ったとしても、それを落としてわざわざインストーラー通してまでやりたいかって
いうとそうじゃない気がしてる。こういう小ぶりなのって試して気に入ったら遊ぶけど、そんなでもなければすぐ消しちゃうだろうし。

Cとかで作られてるフリーアプリとかってレジストリとかいじらない気軽なものが多いし。
セキュリティの関係でなんかあると一気にアドビに裁判で賠償請求とか出されちゃうのを懸念してなのかな？
そんなこと本当に起こるのかな。どうなんでしょ。

オリンピック

仕事の合間にちょろちょろと見てました。

オリンピックは４年に一度だからドラマがあると思いました。あれ、毎年開催してたら全然別物でしたよね。
ありがたみも全然違うっていうか、４年間貯めに貯めたパワーをうわっ！と出すっていうか。
スポーツ選手の現役時代ってすごく短くて、だいたい３０代ぐらいまでだと思うので、
オリンピックに出られる回数も本当に少ないんだと思います。
なんで４年に１度にしたんだろ？そういやワールドカップも４年に１度だし。なんかあるのかな？
うるう年？？？？？謎です。

フィギアも面白かったです。で、やっぱりトップ２の戦いは本当にすごくて、いろいろ肩にかかってくる
ものもあったと思ったのですが、それにおしつぶされずに力を出せたのはすごいと思いました。

浅田さんは、ちと出し切れない部分もあったかもしれないですけど、あれは周りとのプレッシャーじゃなくて
自分とのプレッシャーの中でのことのような気がしています。違うかもしれんけど。

それと、どうでもいいんですけど、国際スケート連盟会長の名前が
オッタビオ・チンクアンタ会長
だってことを知ったことが一番の収穫です。なんかマンガに出てきそうな名前ですよね。
すみません。本当どうでもいいですね。
前のサマランチ会長とかもいい名前だったし。あ、会長の名前はもういいですね。

ビフォー・アフター

テレ朝系のリフォーム番組です。

あれ、いつも思うんですけど、基礎は必ず残すんですよね。どんなにへばってても。補強して再利用。
やっぱり基礎を壊してさら地にするのは番組的にダメなんですかね。
絶対にリフォームじゃないとダメなのかな。
それとも基礎って結構高いのかな。

あと、気になるところは、どこまで依頼者と匠の間で施工前に打ち合わせが行われているかということ。
依頼者が最後リフォーム完了後に、普通に驚いているところを見ると、

・依頼者と匠の間で何度か打ち合わせ、リフォームの方向性を確認
・子ネタ（組みあわせ箱系）などは教えない
・細かい設計図や仕様は見せない。（ここが微妙なところで基本設計図までは見ている気がする）
・基本、施工中の建物の見学はしない（中には見に来る場合もアリ）

ってところでしょうかね。金額が金額なだけに、番組とはいえども後からトラブルにならないように
することを考えると、やっぱり設計図までは見せているのかもなあ。

で、人気の秘密なんですが、コンセプトは「水戸黄門」なんだと思うんです。

・住まいのことで困っている家族がいる。
・匠登場
・匠の技術やアイデアを使い、見事に住まいが再生
・家族大喜び
・一件落着。めでたしめでたし

水戸黄門と同じように、毎回必ず最後は困っていた家族が「ありがとうございます！」と笑顔で匠に感謝した後、
新しい住まいで新しい日々を迎える。という安心感。
匠側にたつ人からみると、家族から感謝され「やったー」
家族側にたつ人からみると、新しい住まいで新しい生活「やったー」
みたいな。大いなるマンネリ（決して悪い意味じゃないです）安心感。

それで、ここも重要なんですけど、一般の人が人生のうちで家を建てたりリフォームすることなんてほんの数回あるかないか。だからこそ、希少価値があります。
で、そんな他人のリフォームなんかを、ビタ一文払わず（ここ重要！）に娯楽として楽しめる。
ってところが良いんでしょうかね。

さて、今回はフリーランス３年目の壁というお話です。
私は独立してからおかげさまで今月で２年２ヶ月となりました。なので、ちょうど３年目にあたります。
独立したばかりのころ、以前お世話になった専門の先生（教科書とか幼児向け雑誌なんかのイラストを書かれていて、スタッフを3人ほど雇い、その道うん十年という方）とお話することがありまして。
話をまとめると

・フリーランスとして独立してきた人を何人も見てきた（業界的に多いですよね）
・だけど、3年もつ人は少ない
・3年もてばあとはなんとかなる（たぶん基盤みたいなものができるんでしょう）
・1年目２年目は勢いがあるので、仕事は意外ととれる。だけどその後が続かない。
・儲かると思ってそっちの方ばかり目を向けていると、儲かる仕事はそれっきりなことが多い
・だから儲からない仕事も大事にした方がよい。終わったように見えても、意外と続いていくことが多い
・短期でキツいけどお金のサイクルが早い仕事と、長期でゆるやかだけどお金のサイクルが長い仕事。この２つをバランスよくしよう
・忙しいといって今の仕事だけに目を向けていると、その仕事が終わったときに次の仕事がないことがある。
・だから今の仕事は、ある意味「終わった仕事」として次の３ヶ月を乗り切る仕事にも目を向けておこう

てな感じでした。それまで私は制作しかしたことがなく、営業やお金まわりのことをほとんどやったことがありませんでした。なので、当初はいまいち実感がわきませんで、「そういうもんかなー？」と思っていました。
自分で当初ポツポツと売り込み営業をしたりしながら、今までやってきたのですが、やっぱり新規の営業はすごく大変です。なんていうか、いったいどこから芽がでてくるのかわからないのに、種をまいている感じ？

で、商売の基本はやっぱり「お得意さま」。つまりリピーターですよね。
リピーターっていうのは、自分の技術を買ってくれている部分もあると思うのですが、
もっというと「信頼」を買ってくれてるのかもなー。とも思ったりします。
とあるところに書いてあったのですが、会社にとって一番の財産は「お金」でもなく「人（従業員）」でもなく「信頼」のようです。お金は使えばおしまい。人も変わっていきます。けれど、信頼さえあればまた新たな仕事が発生するので、またお金と人がまわりだす。みたいな。
信頼はある意味ブランドともいえるような。
「この人だったら、きっとうまくやってくれるだろう」みたいにお客様に思ってもらえたら、たぶんそれがその人のブランドなんでしょう。

なんだかまとまりがなくなっちゃいましたね。
毎日こういうことばっかり考えているわけじゃないんですが、仕事がうまくいったり、意外とキツイ仕事だったりだとか、そういうときにチラリと頭の片隅で考えることはあります。

でまあ、最初に書きましたとおり、私は今３年目なので何とか来年のお正月を無事に迎えたいなーと思ってる次第です。
ではでは。

アルファチャンネルつき動画のやりとりメモです。

■AfterEffects→普通の動画形式に書き出し
形式 > Video For WIndows　か　QuickTimeムービー
出力モジュール設定 > ビデオ出力 > チャンネル > RGB + アルファ

これで書き出した動画をAfterEffectsとかPremireで、またアルファチャンネルつきでよみこめます。
Media Encoderでも読み込めるのでそこからflvに落としてもよいかと。

■AfterEffectsから直接flv書き出し
形式 > Adobe Flash Video
ビデオ出力 > 形式オプション > タブ　ビデオ > 基本ビデオ設定 > アルファチャンネルをエンコードにチェック

—-
flvにできたらあとはFlashでどうにもできるので大丈夫だと思います。

さてThread（そうめん）を、再度勉強しているところです。

Threadは、非同期処理が結構柔軟にかけると思いました。
非同期処理の手続きを開始したあとは、その非同期処理を中止するか、終わるのをひたすら待つかのどちらかなのですが、Threadは非同期処理中の動作を細かく設定できるんですね。だから、ゲームやサーバーと頻繁にデータの出し入れなんかするときに結構役に立つと思います。

で、BetweenAS3です。
これはTweenerと同じ、アニメーション用のライブラリです。
一見複雑そうに見えたのですが、基本はBetweenAS3.toさえ使えればTweenerの代わりにすぐ使えるようになりました。

それで、Thread用にBetweenAS3Threadを作りました。

package
{
	import fl.motion.ITween;
	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.core.easing.IEasing;
	import org.libspark.betweenas3.tweens.IObjectTween;
	import org.libspark.thread.IMonitor;
	import org.libspark.thread.Monitor;
	import org.libspark.thread.Thread;

	public class BetweenThread extends Thread
	{
		private var _target:Object;
		private var _to:Object;
		private var _time:Number;
		private var _easing:IEasing;
		private var _delay:Number;
		private var _monitor:IMonitor;
		private var _tween:IObjectTween;

		public function BetweenThread(target:Object, to:Object, time:Number = 1.0, easing:IEasing = null, delay:Number = 0)
		{
			_target = target;
			_to = to;
			_time = time;
			_easing = easing;
			_delay = delay;
			_monitor = new Monitor();
		}

		override protected function run():void
		{
			_monitor.wait();
			interrupted(interruptedHandler);
			_tween = BetweenAS3.to(_target, _to, _time, _easing);
			if (_delay != 0) {
				BetweenAS3.delay(_tween, _delay);
			}
			_tween.onComplete = completeHandler;
			_tween.play();
		}

		public function cancel():void
		{
			interrupt();
		}

		private function completeHandler():void
		{
			_monitor.notifyAll();
		}

		private function interruptedHandler():void
		{
			if (_tween != null && _tween.isPlaying) {
				_tween.stop();
			}
		}
	}

}

TweenerThreadを参考にしながら作りました。
ところが、さっき検索かけたらすでにさくーしゃさんがBetweenAS3Threadを作られていました。

>> BetweenAS3Thread

それで気がつきました。そうだよなー。コンストラクタの引数をITweenにしておけばBetweenAS3.toに固定しなくてすむもんなー。頭いいなー。と
BetweenAS3はパラレル・シリアルの複数トゥイーンを制御するグループ機能があるので、そっちの方が使い勝手がよいと思いました。
なのでさくーしゃさん方式で今後はいきたいと思いました。

F-siteのセミナーに行ってきました。
今回からスタッフとして参加です。
内容はケータイFlash。
つまりFlash Liteの話を中心に、技術的な話だけでなく、仕事の進め方なども交えて講義がありました。
LISMOや深海ワンダーなどの実例も紹介されました。なかなかこういう機会はないと思うので、とても面白かったです。
ケータイの面白いところは、リアルタイム性にあるみたいです。
岡田さんの講義中に、デモ用のケータイサイトからボタンを押すとプレゼンの画面にニコニコ動画のように「へぇー」やコメントがたくさん流れたりしてました。
岡田さんはサービス精神旺盛な方なようでした。
講義の最後に「TBS系のオールスター感謝祭」と同じようなゲームが出てきて、それを使ってご自分の本のプレゼント大会をしてました。これには驚きました。「アンサーチェック！」とかいうと、リアルタイムにケータイからの投票状況がランキングされてプレゼン画面に出ていたので。演出も本物そっくりで、すごかったです。

さてさてswfaddressです。

>>画像クリックで別ウインドウがひらきます。

>> 今回のソース一式

swfaddressはJavaScriptとFlashを連携させて、ディープリンクを実現するライブラリです。
ディープリンクというのは、通常Flashだけだと内部にURLを直接そのままだと貼ることができないのですが、ページ内リンク（#ではじまるやつです）を使うことによって実現しようというやつです。

で、今まで試したことがなかったんですが今回やってみました。
そしたら意外と基本は難しくなくて素朴な仕組みでした。

１．ASで、SWFAddressのイベントをリスナー登録しておく
２．ASで、SWFAddress.setValue(’設定したいURL’);をする
３．SWFAddressがJSと連携プレー。ブラウザのURLを変更する。SWFAddressがASのイベントをdispatch
４．ASでイベント登録していた関数がよばれる。
５．関数の中でSWFAddress.getValue();をすると現在のURLが読み込めるので、switchやif文で分岐

が基本の流れです。他にもいろいろと機能はあるみたいですが、基本はこれで十分かと。
feb19.jpさんのブログ記事が詳しいです。
>> AS3 で SWFAddress 2.4 を使う ( Flash でブラウザの戻るボタン、パーマリンクに対応する )

もう少し、簡単に知りたい！という方は、本家のチュートリアル集からこのページがおすすめ
>>SWFAddress ActionScript 3 sample for Flash

で、ここまでできたのですが、２階層目以降の場合は結構難しそうですね。
URLを判別して再帰処理をして画面を積み上げていくのかな？と今考えていますけど、いろいろ試してみないとなんともですね。

今回のメインのソースです。

package
{
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.MouseEvent;
	import org.libspark.next.*;
	import swfaddress.SWFAddress;
	import swfaddress.SWFAddressEvent;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Main extends MovieClip
	{
		private var _childPage:BasePage;
		public var btn1:MovieClip;
		public var btn2:MovieClip;

		public function Main()
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			SWFAddress.addEventListener(SWFAddressEvent.INIT, initHD);
		}

		private function initHD(e:SWFAddressEvent):void
		{
			SWFAddress.removeEventListener(SWFAddressEvent.INIT, initHD);
			SWFAddress.addEventListener(SWFAddressEvent.CHANGE, addressChangeHD);
			btn1.addEventListener(MouseEvent.CLICK, btn1ClickHD);
			btn2.addEventListener(MouseEvent.CLICK, btn2ClickHD);
		}

		private function btn2ClickHD(e:MouseEvent):void
		{
			SWFAddress.setValue("/2");
		}

		private function btn1ClickHD(e:MouseEvent):void
		{
			SWFAddress.setValue("/1");
		}

		private function addressChangeHD(e:SWFAddressEvent):void
		{
			var self:Main = this;
			N.push(stopPage).func(function() {
				self.stopPageCompleteHD();
			}).start();
		}

		private function stopPageCompleteHD():void
		{
			var self:Main = this;
			switch(SWFAddress.getValue()) {
				case "/":
				SWFAddress.setTitle("トップページ");
				break;
				case "/1":
				_childPage = new Page1();
				SWFAddress.setTitle("1ページ目");
				break;
				case "/2":
				_childPage = new Page2();
				SWFAddress.setTitle("2ページ目");
				break;
			}

			if (_childPage != null) {
				addChild(_childPage);
				N.push(self._childPage.startPage)
				.func(function() {
				}).start();
			}
		}

		private function stopPage():ITrigger
		{
			var tri:Trigger = new Trigger();
			var self:Main = this;
			if (_childPage == null) {
				tri.call();
			}else{
				N.push(_childPage.stopPage)
				.func(function() {
					self.removeChild(self._childPage);
					self._childPage = null;
					tri.call();
				}).start();
			}
			return tri;
		}
	}

}

あとページ共通の親クラス

package
{
	import flash.display.MovieClip;
	import kinkuma.BAS3Trigger;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.next.*;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class BasePage extends MovieClip
	{

		public function BasePage()
		{

		}

		public function startPage():ITrigger
		{
			var tri:Trigger = new Trigger();
			alpha = 0;
			N.push(BAS3Trigger, this, {	alpha:1 }, 0.5, Quad.easeIn)
			.func(function() {
				tri.call();
			}).start();
			return tri;
		}

		public function stopPage():ITrigger
		{
			var tri:Trigger = new Trigger();
			N.push(BAS3Trigger, this, {	alpha:0 }, 0.5, Quad.easeIn)
			.func(function() {
				tri.call();
			}).start();
			return tri;
		}
	}

}

ではでは。

さて、前回のシーケンス遷移の続きです。
今回は前回のものに、非同期処理を加えてみました。
シーンのイベント処理はProgressionを参考にしました。

>> ファイル一式

非同期処理にはNextを使います。
>> Next は非同期処理を簡素に記述するために作られたライブラリです。

やり方にはちょっとクセがあるのですが、JavaScriptでjQueryをさわったことがある人だったらすぐに慣れると思います。
非同期処理には、他にもたくさんあります。
>> 非同期処理 (AS3) （Spark project）
このほかにもProgressionのCommandやfladdictさんのCommandもありますね。
>> AS3で非同期処理を行う為のcommandsライブラリ

で、Nextは非同期処理をクラスを個別につくらなくても、関数単位でも組み込むことができるお手軽さがウリだと思います。
ソースを書く量が減らせて、面倒くさがりな私にはぴったりです。

それで、今回はシーン移動のときの非同期処理に使いました。
すべてのシーンのベースとなるSceneBase は前回と比べてinit関数はやめてstartSceneとstopSceneのみにしました。

package test.base
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import org.libspark.next.*;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class SceneBase extends MovieClip
	{
		protected var _nextScene:SceneBase;
		protected var _trigger:Trigger;

		public function getNextScene():SceneBase
		{
			return _nextScene;
		}

		public function SceneBase()
		{

		}

		public function startScene():ITrigger
		{
			_trigger = new Trigger();
			_trigger.call();
			return _trigger;
		}

		public function stopScene():ITrigger
		{
			_trigger = new Trigger();
			_trigger.call();
			return _trigger;
		}

		protected function dispatchCompleteEvent():void
		{
			dispatchEvent(new Event(Event.COMPLETE));
		}
	}

}

メインはこんな感じ

package  test
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import org.libspark.next.*;
	import test.base.SceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Main extends MovieClip
	{
		private var _childScene:SceneBase;

		//シングルトン
		private static var _instance:Main;
		public static function getInstance():Main
		{
			return _instance;
		}

		public function Main()
		{
			if (_instance == null) {
				_instance = this;
				init();
			}else{
				throw new Error('Error. This is singleton class.');
			}
		}

		private function init():void
		{
			_childScene = new TopScene();
			_childScene.addEventListener(Event.COMPLETE, childSceneCompleteHD);
			_childScene.startScene();
			addChild(_childScene);
		}

		private function childSceneCompleteHD(e:Event):void
		{
			_childScene.removeEventListener(Event.COMPLETE, childSceneCompleteHD);
			var tempScene:SceneBase = _childScene.getNextScene(); //一時保存
			var self:Main = this;

			//マウス無効
			setMouseEventEnable(false);

			//終了処理
			N.push(_childScene.stopScene)
			.func(function(){;
				self.removeChild(self._childScene);
				self._childScene = null;
				self._childScene = tempScene;
				self.startChildScene();
			}).start();
		}

		//新シーン処理
		private function startChildScene():void
		{
			var self:Main = this;
			N.push(self._childScene.startScene)
			.func(function() {
				self._childScene.addEventListener(Event.COMPLETE, self.childSceneCompleteHD);
				self.setMouseEventEnable(true);
			}).start();
			addChild(_childScene);
		}

		//マウスイベントをとるか
		public function setMouseEventEnable(isPossible:Boolean):void
		{
			this.mouseChildren = this.mouseEnabled = isPossible;
		}
	}

}

ここで、マウスイベントをとるかとらないかという関数をつくってあります

		//マウスイベントをとるか
		public function setMouseEventEnable(isPossible:Boolean):void
		{
			this.mouseChildren = this.mouseEnabled = isPossible;
		}

これはどういうものかというと、非同期処理の最中にボタンを押されるといろいろと面倒なことになるので、それを防ぐためにつけてあります。

ルート以下につるしてあるすべてのマウスイベントを一時的にオン・オフすることができるというものです。作成するアイデアとなったのは、下のページです。
どうもです。
>> AS3.0 マウスイベントの伝播の理解とTIPS ( flair4 blog )

オプションページはこんな感じ

package test
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import kinkuma.BAS3Trigger;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.next.*;
	import test.base.SceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OptionScene extends SceneBase
	{
		public var titleBtn:MovieClip;
		public var startBtn:MovieClip;

		public function OptionScene()
		{

		}

		override public function startScene():ITrigger
		{
			var self:OptionScene = this;
			var tr:Trigger = new Trigger();
			alpha = 0;
			N.push(BAS3Trigger, this, { alpha:1 }, 0.6, Quad.easeIn)
			.func(function(){
				self.startBtn.addEventListener(MouseEvent.CLICK, startClickHD);
				self.titleBtn.addEventListener(MouseEvent.CLICK, titleClickHD);
				tr.call();
			}).start();
			return tr;
		}

		private function startClickHD(e:MouseEvent):void
		{
			_nextScene = new GameScene();
			dispatchCompleteEvent();
		}

		private function titleClickHD(e:MouseEvent):void
		{
			_nextScene = new TopScene();
			dispatchCompleteEvent();
		}

		override public function stopScene():ITrigger
		{
			startBtn.removeEventListener(MouseEvent.CLICK, startClickHD);
			titleBtn.removeEventListener(MouseEvent.CLICK, titleClickHD);
			var tr:Trigger = new Trigger();
			N.push(BAS3Trigger, this, { alpha:0 }, 0.4, Quad.easeIn)
			.func(function() {
				tr.call();
			}).start();
			return tr;
		}
	}

}

ここで、BAS3Triggerというクラスがでてきました。
今回トゥイーンエンジンはBetweenAS3を使っているので、それ用のTriggerクラスを作っています。

package kinkuma
{
	import flash.display.DisplayObject;
	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.core.easing.IEasing;
	import org.libspark.betweenas3.events.TweenEvent;
	import org.libspark.betweenas3.tweens.ITween;
	import org.libspark.next.*;

	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class BAS3Trigger extends Trigger
	{
		private var _tw:ITween;

		public function BAS3Trigger(target:Object, params:Object, time:Number, easing:IEasing, delay:Number = 0)
		{
			_tw = BetweenAS3.to(target, params, time, easing);
			_tw = BetweenAS3.delay(_tw, delay);
			_tw.addEventListener(TweenEvent.COMPLETE, tweenCompHD);
			_tw.play();
		}

		override public function halt(... args:Array):void
		{
			_tw.removeEventListener(TweenEvent.COMPLETE, tweenCompHD);
			_tw.stop();
		}

		private function tweenCompHD(e:TweenEvent):void
		{
			_tw.removeEventListener(TweenEvent.COMPLETE, tweenCompHD);
			call();
		}

	}

}

あと、節となるゲームシーン

package test
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import test.base.GameSceneBase;
	import test.base.SceneBase;
	import kinkuma.BAS3Trigger;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.next.*;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class GameScene extends SceneBase
	{
		public var popupBtn:MovieClip;
		public var titleBtn:MovieClip;
		private var _childScene:SceneBase;

		public function GameScene()
		{

		}

		override public function startScene():ITrigger
		{
			var self:GameScene = this;
			var tr:Trigger = new Trigger();
			alpha = 0;
			N.push(BAS3Trigger, this, { alpha:1 }, 0.6, Quad.easeIn)
			.func(function() {
				self.popupBtn.addEventListener(MouseEvent.CLICK, self.popupClickHD);
				self.titleBtn.addEventListener(MouseEvent.CLICK, self.titleClickHD);
				tr.call();
			}).start();
			return tr;
		}

		private function popupClickHD(e:MouseEvent):void
		{
			_childScene = new PopupScene();
			addChild(_childScene);
			var self:GameScene = this;
			Main.getInstance().setMouseEventEnable(false);
			N.push(_childScene.startScene)
			.func(function() {
				self._childScene.addEventListener(Event.COMPLETE, self.childSceneCompleteHD);
				Main.getInstance().setMouseEventEnable(true);
			}).start();
		}

		private function childSceneCompleteHD(e:Event):void
		{
			_childScene.removeEventListener(Event.COMPLETE, childSceneCompleteHD);

			Main.getInstance().setMouseEventEnable(false);

			var self:GameScene = this;
			N.push(_childScene.stopScene)
			.func(function() {
				self.childSceneTransitionCompleteHD();
				Main.getInstance().setMouseEventEnable(true);
			}).start();
		}

		private function childSceneTransitionCompleteHD():void
		{
			removeChild(_childScene);

			_nextScene = _childScene.getNextScene();

			//何もしない
			if (_nextScene == null) {

			//GameSceneの子シーンになれるんだったら
			}else if (_nextScene is GameSceneBase) {
				/*
				 * 子シーンを追加してchildSceneCompleteHDを登録する処理
				 * 今回は別の子シーンがないので何もしない
				 */

			//子シーンでない場合は親に通達する
			}else {
				dispatchCompleteEvent();
			}
		}

		private function titleClickHD(e:MouseEvent):void
		{
			_nextScene = new TopScene();
			dispatchCompleteEvent();
		}

		override public function stopScene():ITrigger
		{
			popupBtn.removeEventListener(MouseEvent.CLICK, popupClickHD);
			titleBtn.removeEventListener(MouseEvent.CLICK, titleClickHD);
			var tr:Trigger = new Trigger();
			N.push(BAS3Trigger, this, { alpha:0 }, 0.4, Quad.easeIn)
			.func(function() {
				tr.call();
			}).start();
			return tr;
		}
	}

}

なんか長々となってしまいました。興味がある方はソースを見てみてください。
これにswfaddressを組み込めれば、簡易自作ページ遷移システムになると思います。でもこれがすごく厄介そうだなー。

ではー。

さて、今回はシーケンス遷移を自作してみようと思います。
シーケンス遷移は、ゲーム業界で使われている用語のようです。
普通にいうとページ遷移です。
なんでゲーム業界のことなんか出てくるんだ？といいますと、今回は下の本を参考に作ったからなのです。

>> ゲームプログラマになる前に覚えておきたい技術

これはセガの中の人が書いた本です。C++の本なのですが、考え方は別の言語でも
使えるということでAS3で拝借しました。
この本の中でシーケンス遷移は２章割かれていまして、簡単なのと難しいのがあります。
今回は難しい方をやってみようと思います。
もっとも、難しいといってもオブジェクト指向やデザインパターンなどを熟知している人からしたらすごく簡単だと思います。
私には難しかったです。

さて、今回のデモ

>> ファイル一式

　
シーケンスやページという呼び方でもいいんですが、今回はProgressionに習って
シーンという呼び方にします。
シーン構成はこんな感じ。

Main（シーンなしこれを基底とする）
　┣　タイトルシーン
　┣　オプションシーン
　┣　ゲームシーン
　　　　┣　ポップアップシーン

Main直下に、タイトル・オプション・ゲームが並んでいて、
ゲームにポップアップがぶら下がっている形。
ゲームが表示されている上にポップアップが出ていることに注目してください。

各シーンはSceneBaseを継承しています。

package test.base
{
	import flash.display.MovieClip;
	import flash.events.Event;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class SceneBase extends MovieClip
	{
		protected var _nextScene:SceneBase;

		public function getNextScene():SceneBase
		{
			return _nextScene;
		}

		public function SceneBase()
		{

		}

		public function init():void
		{

		}

		public function startScene():void
		{

		}

		public function stopScene():void
		{

		}

		protected function dispatchCompleteEvent():void
		{
			dispatchEvent(new Event(Event.COMPLETE));
		}
	}

}

ポップアップだけがSceneBaseを継承したGameSceneBaseをさらに継承しています。

package test.base
{
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class GameSceneBase extends SceneBase
	{

		public function GameSceneBase()
		{

		}

	}

}

それで、親と子の同階層間移動の基本方針は以下のようになります。

１）一番最新の子（画面手前）が自分の次のシーンを決めてnewする
２）親は子供からEvent.Completeを受け取ったあと、子供から次のシーンの情報をもらう。
３）親は現在の子供をstopSceneして、次のシーンをinitし、startSceneする。
４）親は次のシーンにaddEventLitener(Event.Complete)して待機
１）に戻る

ここで、全てのシーンはSceneBaseを継承しているので、親は子供が言ってきた次のシーンが何であるかわからないまま進めることができます。
Mainの初期化のときだけ最初のシーンを決めますが、あとは子供の言うとおり「はいはい、次はそのシーンね」みたいな感じですすめられます。

さきほどのセガの参考書の簡単な方の章では、別のやり方をしています。
１）子供の中でnewするのではなくて、子供が次のシーンの番号だけを保持しておく
２）親は子供の番号を見て次のシーンを分岐、親がnewする

ここで、今回のやり方との違いは親と子供の仕事の分担です。
親がnewする場合は、次に行くシーンの数だけif文が親の中に並ぶことになります。
それだと、シーンの数が増えた場合に可読性が下がるので、子供の方で分岐を分割してあげようというのが今回の方針です。
たとえば次の行き先が全部で10あったとしても、一人の子供が示す次の行き先は2～3である場合があるからです。

ちなみに、本の方ではC++を使っているので、newした参照ではなくポインタを渡していました。newした参照とポインタって同じもんだと思ってるんですけど、ちょっと違うんでしょうかね？？このあたりよくわかりません。

Mainのソース

package  test
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import test.base.SceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Main extends MovieClip
	{
		private var _childScene:SceneBase;

		public function Main()
		{
			init();
		}

		private function init():void
		{
			_childScene = new TopScene();
			_childScene.init();
			addChild(_childScene);
			_childScene.startScene();
			_childScene.addEventListener(Event.COMPLETE, childSceneCompleteHD);
		}

		private function childSceneCompleteHD(e:Event):void
		{
			_childScene.removeEventListener(Event.COMPLETE, childSceneCompleteHD);
			var tempScene:SceneBase = _childScene.getNextScene(); //一時保存

			//終了処理
			_childScene.stopScene();
			removeChild(_childScene);
			_childScene = null;

			//新シーン処理
			_childScene = tempScene;
			_childScene.init();
			addChild(_childScene);
			_childScene.startScene();
			_childScene.addEventListener(Event.COMPLETE, childSceneCompleteHD);
		}
	}

}

タイトル画面 TopScene

package test
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import test.base.SceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class TopScene extends SceneBase
	{
		public var startBtn:MovieClip;
		public var optionBtn:MovieClip

		public function TopScene()
		{

		}

		override public function init():void
		{
			super.init();
		}

		override public function startScene():void
		{
			startBtn.addEventListener(MouseEvent.CLICK, startClickHD);
			optionBtn.addEventListener(MouseEvent.CLICK, optionClickHD);
			super.startScene();
		}

		private function optionClickHD(e:MouseEvent):void
		{
			_nextScene = new OptionScene();
			dispatchCompleteEvent();
		}

		private function startClickHD(e:MouseEvent):void
		{
			_nextScene = new GameScene();
			dispatchCompleteEvent();
		}

		override public function stopScene():void
		{
			startBtn.removeEventListener(MouseEvent.CLICK, startClickHD);
			optionBtn.removeEventListener(MouseEvent.CLICK, optionClickHD);
			super.stopScene();
		}
	}

}

オプションシーンはタイトルシーンとほぼ同じなので省略。
親と子供を両方もち、処理が複雑になるゲームシーンについて。

今回、ゲームからポップアップを開いたあとに、ゲームシーンから見て、ポップアップをただ閉じるだけという場合と、自分を飛び越えて自分の兄弟であるタイトル画面へ行くという仕様にしました。

ゲームシーンの子シーンは全てGameSceneBaseを継承するようにします。
そうしたときに、
if(次のシーン is GameSceneBase)
と型判定をすると自分にまだ関係があるかどうかわかります。
もし自分にもう関係ないや、ということであれば自分の親、つまりこの場合はMainに判定してもらおう。という仕組みです。
その場合、自分にはもう関係ないのでゲームシーンがイベントを発行して親にひろってもらいます。

GameScene

package test
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import test.base.GameSceneBase;
	import test.base.SceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class GameScene extends SceneBase
	{
		public var popupBtn:MovieClip;
		public var titleBtn:MovieClip;
		private var _childScene:SceneBase;

		public function GameScene()
		{

		}

		override public function init():void
		{
			super.init();
		}

		override public function startScene():void
		{
			popupBtn.addEventListener(MouseEvent.CLICK, popupClickHD);
			titleBtn.addEventListener(MouseEvent.CLICK, titleClickHD);
			super.startScene();
		}

		private function popupClickHD(e:MouseEvent):void
		{
			_childScene = new PopupScene();
			_childScene.init();
			addChild(_childScene);
			_childScene.startScene();
			_childScene.addEventListener(Event.COMPLETE, childSceneCompleteHD);
		}

		private function childSceneCompleteHD(e:Event):void
		{
			_childScene.removeEventListener(Event.COMPLETE, childSceneCompleteHD);
			_childScene.stopScene();
			removeChild(_childScene);

			_nextScene = _childScene.getNextScene();

			//何もしない
			if (_nextScene == null) {

			//GameSceneの子シーンになれるんだったら
			}else if (_nextScene is GameSceneBase) {
				/*
				 * 子シーンを追加してchildSceneCompleteHDを登録する処理
				 * 今回は別の子シーンがないので何もしない
				 */

			//子シーンでない場合は親に通達する
			}else {
				dispatchCompleteEvent();
			}
		}

		private function titleClickHD(e:MouseEvent):void
		{
			_nextScene = new TopScene();
			dispatchCompleteEvent();
		}

		override public function stopScene():void
		{
			popupBtn.removeEventListener(MouseEvent.CLICK, popupClickHD);
			titleBtn.removeEventListener(MouseEvent.CLICK, titleClickHD);
			super.stopScene();
		}
	}

}

package test
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import test.base.GameSceneBase;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class PopupScene extends GameSceneBase
	{
		public var titleBtn:MovieClip;
		public var closeBtn:MovieClip;

		public function PopupScene()
		{

		}

		override public function init():void
		{
			super.init();
		}

		override public function startScene():void
		{
			closeBtn.addEventListener(MouseEvent.CLICK, closeClickHD);
			titleBtn.addEventListener(MouseEvent.CLICK, titleClickHD);
			super.startScene();
		}

		private function closeClickHD(e:MouseEvent):void
		{
			_nextScene = null; //画面を閉じたあと兄弟シーンにいくわけでないのでnull
			dispatchCompleteEvent();
		}

		private function titleClickHD(e:MouseEvent):void
		{
			_nextScene = new TopScene();
			dispatchCompleteEvent();
		}

		override public function stopScene():void
		{
			closeBtn.removeEventListener(MouseEvent.CLICK, closeClickHD);
			titleBtn.removeEventListener(MouseEvent.CLICK, titleClickHD);
			super.stopScene();
		}
	}

}

SceneBaseにinit, startScene, stopSceneがありますが、本の方ではそういう風な関数はまったくありません。あと本は、こういったイベント駆動の方式ではなくて、毎フレーム次のシーンを返してreturn nextScene;みたいにして、親の方で判定する方式です。
なので、今回のはAS3向けにアレンジしてますので、ちゃんとしたやつが見たい方は本の方を見てください。

次回はこれに非同期処理を加えたいと思います。
非同期処理はいろいろあるのですが、前から愛用しているNextを使ってみようと思っています。

タイムライン上に配置したストリーミングサウンドは、MovieClip自体を停止しないと
ストリーミングが永久に続く。

特に注意しなければいけないのが、タイムラインにストリーミングサウンドを貼り付けたMCが入っているswfを
外部ファイルとしてloaderで読み込んだとき。
loader.unloadをやっても、何をやってもそのままだとストリーミングサウンドがなり続ける。
解決策としては、unloadする前にMCをstopしてあげること。

タイムラインに貼り付けるのが「ストリーミング」ではなく「スタート」であれば、unloadするだけで音は消える。

本当はSoundChannelをstopできればよいのだが、タイムライン上でなっているサウンドのSoundChannnelが
どうやって取得できるのかがわからないためこうする。

タイムライン上の音量はmc.soundTransformで変更できる。クラスファイル内ではthis.soundTransformで。
全体の音量調整はSoundMixer.soundTransformで変更できる。
ただ、SoundMixerは個別の音量調整ができない。