ここ2～3か月でみた映画とアニメのリストなど書いてみます。

映画

■告白
心をわしづかみにされた。

■インセプション
最後のシーンがすごく気になった。

■トイ・ストーリー３
ウッディが最後の方に目にした光景でする決断にやられた。

■カラフル
最初、「椿山課長の七日間」なのかなーと思ったら違った。登場人物の描写が丁寧でよかった。

■スカイクロラ
押井監督のはいつもよくわかんなくて面白いかもわかんないんだけど、見てる。

■レミーのおいしいレストラン
結構リアルなネズミが調理場で料理するのになじめなかったんだけど、面白かった。
もちっと見た目をコミカルなキャラっぽくしてほしかったな。

アニメ

■東のエデン
映画版をみてみたい。

■デュラララ!!
勉強会で教えてもらったのでみてみたら、電脳コイル並みに先が気になる話だった。面白い。

■青い花
いわゆる百合系ってやつかな？原作のマンガを読んでみたい。

感想

自分の好きな傾向としては、
・先の気になるストーリー展開の作品
・ストーリーとしては地味だけど、登場人物の心理描写がすごく丁寧に描かれている作品
が好きみたい。特に後者の心理描写が丁寧に描かれているものの方が心に残る。
２つの要素がともにあって、個人的に神アニメだったのは「電脳コイル」です。

学生の頃とかは、時間もあったし単館系の作品を銀座とかに見に行ったりもしたんだけど、今はぜんぜん。
車でちょっといったところにあるショッピングモールのシネコンだけ。
事前に席も押さえられるし便利。
結果的に、大作映画っていうか、有名どころばっかりなんだけど、それで満足。
なんで、あのころはきばってたのかは今じゃわからない。
実際はそこまで映画好きっていうほど映画が好きなわけじゃなかったんだと思う。

チャリとか歩きで気軽に行けるところにTSUTAYAがないせいか、最近ほとんどDVDとかCDを借りなくなった。
そんで、そんな私のためにあるようなのがバンダイチャンネルとかのオンラインで見れるサイト。

深夜アニメを録画してまでみたいわけじゃなくて、有名どころをそこそこみたいだけなのでちょうどいい感じ。気になったら、一気に全話とか見れてそこもよい。

実写映画の方でもオンラインで見れたらいいなと思って調べてみたら、ひかりTVが気になった。ちょっと料金が高そうだけど気になる。もう少し調べてみよう。

FLVPlaybackは手軽にFLVを再生できるコンポーネントです。
それでそのスキンがたくさん選ぶことができます。

だけど、ボリューム調整と再生ボタンと、あとシークバーとみたいに、それらを自由に選択することが
デフォルトのものだとできないです。決められた組み合わせのみ。

そんで、どうやったらいいのかな？と思ったら、そのスキンのもとFlaがちゃんとありました。

Winだと
C:\Program Files (x86)\Adobe\Adobe Flash CS4\Common\Configuration\FLVPlayback Skins\FLA\ActionScript 3.0

こんな感じにずらーっと並んでいます。

中をひらくとこんなファイルになってました。

そんでこれのカスタマイズなんですけど、基本は増やすよりは減らす方向で進めると楽そうです。
自分のほしいボタンの入っているファイルを探して、そのファイルをコピーします。

絶対にオリジナルはとっておくように、コピーは必ずしておかないとマズいです。

そしたら、Layout Layer(Exported to SWF)という左上のところから必要ないところをどんどん選択して
消去してきます。デリートキーで普通に。
その際に、その消すMCのインスタンス名を覚えておきます。

最後にメインタイムラインの1フレーム目のスクリプトを開きます。

// set up linkages
this.pauseButtonDisabledState = "fl.video.skin.PauseButtonDisabled";
this.pauseButtonDownState = "fl.video.skin.PauseButtonDown";
this.pauseButtonNormalState = "fl.video.skin.PauseButtonNormal";
this.pauseButtonOverState = "fl.video.skin.PauseButtonOver";
this.playButtonDisabledState = "fl.video.skin.PlayButtonDisabled";
this.playButtonDownState = "fl.video.skin.PlayButtonDown";
省略

さきほど消去したインスタンス名の部分を全部コメントアウトか消していきます。したの方まで
ずらーっと並んでいるので、消し忘れのないように。

何行目かにある

this.minWidth = 230;

とかも最少の幅なんで適当に調整するといいかもしれないです。

そんでパブリッシュしてエラーが出なければスキン作成成功。

よみこみ側のFlaファイルのFLVPlaybackのコンポーネントインスペクタパネルを開いて、
パラメータ > skin > カスタムスキンのURLってやったあと、したの入力欄に、
自分で作成したカスタムスキンのswfファイル名を入力すれば完了です。
例）custom_skin.swfとか

ついに！はじめてのiPhoneアプリがリリースされましたよ！
PossessBallといいます。

>> PossessBall (iTunes preview)

これはどういうものかというと、サッカーのボール支配率を自分で測定するためのアプリです。

iPhone片手に試合を見ながら、Aチームの方がボールを持っていると思ったら、Aボタンを押します。
反対に、Bチームの方だと思ったら、Bボタンを押します。
それで、そのときの支配率が下に表示されるというシンプルなアプリです。

この間のワールドカップ見てるときに思いついたんで（笑）　ものすごく「え？いまさら」感の強いものです、、。
ま、ここからじっくり次の４年にむけていきますよ（笑）

本当のとこ、地味ーに高校のサッカー部のコーチとかマネージャーさんが使ってくれたらいいな。とか思ってたりしてます。
あと、サッカーって世界共通なんで、サッカー人口多そう→ニーズはあるかなー。なんて。

今回はいつも苦手なデザインを頑張りました！

チーム名を変更できます

よろしくお願いします！

先日ようやく、はじめてのアプリが完成しまして。
さあ、申請だ！と思って、いろいろと見ていたら、
EINっていうアメリカ納税者番号というのをとらなきゃいけないって書いてありまして。

おお、そうかそうかと、申請して待っていたんですね。
そしたら、待ってても来なくて。うーんどうしてなんだろう？と思ったら、返信する際に使われるFAX番号間違ってましたww
それで訂正しなきゃいけないなーなどと思って、またネットを見ていたら、なんと
「EINはとらなくても申請がOKになりました」っていう情報が！
おー、もっと早く言ってよ。なんていうわけで、EINの訂正はおいておいて、早速アプリの申請をしました。
EINの方はたぶん、FAXが通じないからエアメールで送られてくると思います。
「FAX通じないけどどうなってんの？？」とかいうコメントつきで。

そんで、今は審査待ちな状態です。だいたい1～3週間くらい待たされたり、早い人だと2～3日って場合もあるみたいです。
メーラーのリロード何回も押してるんですが、そうやってても、審査は早くなんないみたいで、まだ着てません。

OpenGL ES

まってる間に、お仕事で必要になったのでOpenGLっていうのを勉強してました。
OpenGLっていうのは3Dのライブラリです。
言語はC言語です。
Windowsの人はDirectXっていうのを聞いたことがある人もいると思うんですが、あれの仲間みたいなやつで、
3Dを描画するための仕組みです。
OpenGLはOSに依存しないように書いてあるので、いったん仕組みがわかってしまえば、
Windows, Mac, スマートフォン（iPhone、Android）あたりでも使えるみたいです。
（ただし、実際は最終的な描画の仕組みが違うので、コアの部分が共通の書き方ができると思われる）

そんで、OpenGL ESっていうのがあって、これはOpenGLの機能限定版みたいなやつです。
OpenGL ESの中にもバージョンがあって、IPhoneで使えるのは、OpenGL ES1.1とOpenGL ES2.0です。
1.1と2.0は仕組みが違ってるみたいで、かつ2.0が使えるのはiPhone 3GSからなので、
基本1.1を使うようです。

あ、ここで気がついたと思うですけど、やっぱりWinでもMacでもAndroidでも使えるってのは
微妙に違いますね。そのままはまず動きませんね。ただ、考え方の根っこ部分は同じだと
思うので、まあできておいたらいいかなと。

本はまずこの本をざっとやりました。

上の本、すごく面白かったです。
自分にとってAS3の思い出の本は、下の本だったりするんですが、
上のゲームプログラミング本はOpenGLのそれにあたりました。
とても良い本です。

そんで、もう少しOpenGLについて知りたいとこの本を購入。

そしたら、おもいっきり難しかったです。
頑張ればわかんなくもなさそうな内容なんですが、結構濃い感じなんで覚悟きめてやらないと！みたいな。
どちらかというと、OpenGL用のライブラリを自作するような内容でした。
まだソースと内容を流し読みした程度にとどまってます。
でも、上のゲームプログラミング本に載っていない、ライティングの話などがのっているので、
こちらは適宜必要に応じてやっていけばいいんじゃないかと思いました。
実際ライティングとかつけなくても、ゲームは作れるんで。

そんで、OpenGL ESは描画できる手段は用意されているんですけど、AS3でいうところのPV3dみたいな
気軽に使えるような定番ライブラリはまだ特になさそうです。
Cubeとかも全部自分で座標を打たないといけないです。

2Dに限定していえば、cocos2dが有名みたいです。
OpenGLにはgluとかglutっていうライブラリがあるみたいで、それのiPhone版も開発されているようです。

ただ、それほど複雑なものでなければ自力でなんとかいけそうだと思いました。
特に2Dの方は。
3Dの方も、複雑なポリゴンを読み込むとか大変ですが、（自作しないといけないので）、
PV3dでいうプリミティブ系のやつ（PlaneとかCubeとか）は自分で座標を書いたりしてできないこともなさそうです。

OpenGL使ってなんかゲームを作ってリリースしてみたいなーと思ってる今日この頃です。
ではでは。

■アプリケーション起動（初回）
1) application:didFinishLaunchingWithOptions
2) applicationDidBecomeActive

■homeボタンを押したとき
1) applicationWillResignActive
2) applicationDidEnterBackground

■もう一度アプリケーションを起動したとき（２回目以降）
1) applicationWillEnterForeground
2) applicationDidBecomeActive

それぞれの役割

中に書いてあるコメントを訳してみる

■application:didFinishLaunchingWithOptions
アプリケーションの起動時。
viewControllerのviewをwindowにaddする

■applicationWillResignActive

    /*
     Sent when the application is about to move from active to inactive state. This can occur for certain types of temporary interruptions (such as an incoming phone call or SMS message) or when the user quits the application and it begins the transition to the background state.
     Use this method to pause ongoing tasks, disable timers, and throttle down OpenGL ES frame rates. Games should use this method to pause the game.
     */

アプリケーションがアクティブからインアクティブな状態に移行するときに呼ばれる。
一時的な中断（電話がかかってきたりSMSメッセージが届いたりといった）ときや、ユーザーがアプリケーションを終了して、バックグラウンド状態になる際におこる。
このメソッドは継続中のタスクをポーズするのに使ってください。タイマーをやめたり、OpenGL ESのフレームレートを下げたりして。
ゲームはこのメソッドをゲームの中断に使用すべきです。

■applicationDidEnterBackground

    /*
     Use this method to release shared resources, save user data, invalidate timers, and store enough application state information to restore your application to its current state in case it is terminated later.
     If your application supports background execution, called instead of applicationWillTerminate: when the user quits.
     */

このメソッドは共有リソースのreleaseに使ってください。ユーザーデータの保存、タイマーの中断、また後でアプリが終了するのに備えて、アプリケーションの状態をもとに戻すために必要な現在の情報の保存。
アプリケーションがバックグラウンドをサポートする場合、ユーザーが終了するときに、applicationWillTerminateの代わりに呼んでください。

■applicationWillEnterForeground

    /*
     Called as part of  transition from the background to the inactive state: here you can undo many of the changes made on entering the background.
     */

バックグラウンドからインアクティブな状態に移るときに呼ばれます。ここで、バックグラウンドによる多くの変更をアンドゥすることができます。

■applicationDidBecomeActive

    /*
     Restart any tasks that were paused (or not yet started) while the application was inactive. If the application was previously in the background, optionally refresh the user interface.
     */

アプリケーションがインアクティブだった間に中断していた（または開始していなかった）タスクを再開します。もしアプリケーションが前にバックグラウンドだった場合、ユーザーインターフェースのリフレッシュをオプションですることができます。

■applicationWillTerminate

    /*
     Called when the application is about to terminate.
     See also applicationDidEnterBackground:.
     */

アプリケーションが中断する際に呼ばれます。applicationDidEnterBackgroundを参照してください。

というわけで、以前に作ったjsflEditを発表してきました。

■画面を一度クリックしたあと、キーボードの左右キーでページ送りができます。

20人くらい参加していて、全員発表しました。
皆さん、こだわるポイントが違っていて、おもしろかったです。

今回は、前回の課題となっていたEnterframeをひとつのクラスにまとめて最適化してみよう。です。

Event.ENTER_FRAMEは、各インスタンスごとに登録すると重くなる原因となります。
なので、UpdateManagerというクラスを作って、それだけがENTER_FRAMEを呼び出して、
そこに各Tweenのインスタンスを追加・削除することにしました。

今回作ったもの。
玉の数を1000個にしてみました。

追加・削除の具体的な仕組みは、各Tweenごとに一意となるキーをもたせます。
それをキーとしてManagerのObjectに登録します。
削除するときはそれをまたキーとして削除しました。

package kuma_de
{
	import flash.display.Sprite;
	import flash.events.Event;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class UpdateManager extends Sprite
	{
		private static var _instance:UpdateManager;
		public static function get instance():UpdateManager
		{
			if (_instance == null) {
				_instance = new UpdateManager();
			}
			return _instance;
		}

		private var _tweens:Object;
		private var _isUpdating:Boolean;
		private var _tweenCount:int;

		public function UpdateManager()
		{
			if (_instance == null){
				_tweens = {};
				_isUpdating = false;
				_tweenCount = 0;
			}
		}

		public function add(tween:OreOreTween, key:String):void
		{
			_tweens[key] = tween
			_tweenCount++;
			if (_isUpdating == false) {
				addEventListener(Event.ENTER_FRAME, update);
				_isUpdating = true;
			}
		}

		public function remove(tween:OreOreTween, key:String):void
		{
			for (var i:String in _tweens) {
				if (i == key) {
					_tweens[key] = null;
					delete _tweens[key];
					_tweenCount--;
				}
			}
			if (_tweenCount == 0) {
				removeEventListener(Event.ENTER_FRAME, update);
				_isUpdating = false;
			}
		}

		private function update(e:Event):void
		{
			var tween:OreOreTween;
			for (var i:String in _tweens) {
				tween = _tweens[i];
				tween.update();
				if (tween.isTweenComplete) {
					_tweens[i] = null;
					delete _tweens[i];
					_tweenCount--;
				}
			}
			if (_tweenCount == 0) {
				removeEventListener(Event.ENTER_FRAME, update);
				_isUpdating = false;
			}
		}
	}

}

■OreOreTween

package  kuma_de
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OreOreTween extends EventDispatcher
	{
		//easing
		public static const EASE_NONE:String = "easeNone";
		public static const EASE_IN_QUAD:String = "easeInQuad";
		public static const EASE_OUT_QUAD:String = "easeOutQuad";
		public static const EASE_IN_OUT_QUAD:String = "easeInOutQuad";
		public static const EASE_OUT_IN_QUAD:String = "easeOutInQuad";
		public static const EASE_IN_CUBIC:String = "easeInCubic";
		public static const EASE_OUT_CUBIC:String = "easeOutCubic";
		public static const EASE_IN_OUT_CUBIC:String = "easeInOutCubic";
		public static const EASE_OUT_IN_CUBIC:String = "easeOutInCubic";
		public static const EASE_IN_QUART:String = "easeInQuart";
		public static const EASE_OUT_QUART:String = "easeOutQuart";
		public static const EASE_IN_OUT_QUART:String = "easeInOutQuart";
		public static const EASE_OUT_IN_QUART:String = "easeOutInQuart";
		public static const EASE_IN_QUINT:String = "easeInQuint";
		public static const EASE_OUT_QUINT:String = "easeOutQuint";
		public static const EASE_IN_OUT_QUINT:String = "easeInOutQuint";
		public static const EASE_OUT_IN_QUINT:String = "easeOutInQuint";
		public static const EASE_IN_SINE:String = "easeInSine";
		public static const EASE_OUT_SINE:String = "easeOutSine";
		public static const EASE_IN_OUT_SINE:String = "easeInOutSine";
		public static const EASE_OUT_IN_SINE:String = "easeOutInSine";
		public static const EASE_IN_EXPO:String = "easeInExpo";
		public static const EASE_OUT_EXPO:String = "easeOutExpo";
		public static const EASE_IN_OUT_EXPO:String = "easeInOutExpo";
		public static const EASE_OUT_IN_EXPO:String = "easeOutInExpo";
		public static const EASE_IN_CIRC:String = "easeInCirc";
		public static const EASE_OUT_CIRC:String = "easeOutCirc";
		public static const EASE_IN_OUT_CIRC:String = "easeInOutCirc";
		public static const EASE_OUT_IN_CIRC:String = "easeOutInCirc";
		public static const EASE_IN_ELASTIC:String = "easeInElastic";
		public static const EASE_OUT_ELASTIC:String = "easeOutElastic";
		public static const EASE_IN_OUT_ELASTIC:String = "easeInOutElastic";
		public static const EASE_OUT_IN_ELASTIC:String = "easeOutInElastic";
		public static const EASE_IN_BACK:String = "easeInBack";
		public static const EASE_OUT_BACK:String = "easeOutBack";
		public static const EASE_IN_OUT_BACK:String = "easeInOutBack";
		public static const EASE_OUT_IN_BACK:String = "easeOutInBack";
		public static const EASE_IN_BOUNCE:String = "easeInBounce";
		public static const EASE_OUT_BOUNCE:String = "easeOutBounce";
		public static const EASE_IN_OUT_BOUNCE:String = "easeInOutBounce";
		public static const EASE_OUT_IN_BOUNCE:String = "easeOutInBounce";

		private var _target:*;
		private var _tweenObjects:Object;
		private var _updateCount:int;
		private var _maxUpdateCount:int;
		private var _isTweening:Boolean;
		public function get isTweening():Boolean
		{
			return _isTweening;
		}
		private var _isTweenComplete:Boolean;
		public function get isTweenComplete():Boolean
		{
			return _isTweenComplete;
		}
		private static var _serialID:int = 0;
		private static const _PRIOR_ID:String = "tween";
		private var _key:String;

		public static function getTweenValues(to:Number, from:Number, duration:Number = 1.0, easing:String = EASE_NONE):Array
		{
			var frameRate:int = 30;//フレームレート

			var values:Array = [];
			var segmentNum:int = Math.floor(frameRate * duration); //分割数

			var i:int;
			var t:Number;
			var dt:Number = 1 / segmentNum;
			var time:Number;
			var value:Number;
			for (i = 0; i <= segmentNum; i++) {
				t = dt * i; //tは0以上1以下の範囲で動く
				time = t * duration; //開始からの時刻（秒）

				value = Equations[easing](time, from, to - from, duration);
				values.push(value);
			}
			return values;
		}

		public function OreOreTween(target:*, to:Object, duration:Number = 1.0, easing:String = EASE_NONE, delay:Number = 0)
		{
			_isTweening = false;
			_isTweenComplete = false;
			_tweenObjects = { };
			_target = target;
			_key = _PRIOR_ID + _serialID;
			_serialID++;

			for (var i:String in to) {
				_tweenObjects[i] = getTweenValues(to[i], target[i], duration, easing);
				_maxUpdateCount = _tweenObjects[i].length;
			}
		}

		public function start():void
		{
			if (!_isTweening)
			{
				_isTweening = true;
				_updateCount = 0;
				var manager:UpdateManager = UpdateManager.instance;
				manager.add(this, _key);
			}
		}

		public function pause():void
		{
			if (_isTweening)
			{
				var manager:UpdateManager = UpdateManager.instance;
				manager.remove(this, _key);
				_isTweening = false;
			}
		}

		public function reset():void
		{
			_updateCount = 0;
		}

		public function resume():void
		{
			if (!_isTweening)
			{
				var manager:UpdateManager = UpdateManager.instance;
				manager.add(this, _key);
				_isTweening = true;
			}
		}

		public function update():void
		{
			//tween終了
			if (_updateCount == _maxUpdateCount)
			{
				_isTweenComplete = true;
				dispatchEvent(new Event(Event.COMPLETE));

			//tween値を適用
			}else {
				var tweenValues:Array;
				var value:Number;
				for (var i:String in _tweenObjects) {
					_target[i] = _tweenObjects[i][_updateCount];
				}
				_updateCount++;
			}
		}
	}
}

のこりのクラス

package
{
	import com.bit101.components.HSlider;
	import com.bit101.components.Label;
	import com.bit101.components.List;
	import com.bit101.components.PushButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import kuma_de.OreOreTween;
	import net.hires.debug.Stats;

	/**
	 * ...
	 * @author KinkumaDesign
	 */
	[SWF(width="450",height="450",backgroundColor="0x000000",frameRate="30")]
	public class Main extends Sprite
	{
		public var balls:Array;
		public var ballNum:int = 1000;
		public var tweens:Array;
		public var startPos:Circle;
		public var endPos:Circle;
		public var startBtn:PushButton;
		public var easingList:List;
		public var durationSlider:HSlider;
		public var opacitySlider:HSlider;

		public var ore:OreOreTween;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			addChild( new Stats() );

			startPos = new Circle(10, 0xE91283, 1, true);
			addChild(startPos);
			startPos.setPosition(50, 100);

			endPos = new Circle(10, 0xE91283, 1, true);
			addChild(endPos);
			endPos.setPosition(400, 200);

			startBtn = new PushButton(this, 250, 380, "start", startBtnClickHD);

			var label:Label = new Label(this, 100, 280, "EASING");
			label.textField.textColor = 0xffffff;
			var easingListItem:Array = getEasingListItem();
			easingList = new List(this, 100, 300, easingListItem);
			easingList.selectedIndex = easingListItem.length - 6;

			label = new Label(this, 250, 280, "DULATION");
			label.textField.textColor = 0xffffff;

			durationSlider = new HSlider(this, 250, 300, null);
			durationSlider.maximum = 2.0;
			durationSlider.minimum = 0.1;
			durationSlider.tick = 0.1;
			durationSlider.value = 1.1;

			label = new Label(this, 250, 320, "OPACITY");
			label.textField.textColor = 0xffffff;
			opacitySlider = new HSlider(this, 250, 340, null);
			opacitySlider.maximum = 1.0;
			opacitySlider.minimum = 0;
			opacitySlider.tick = 0.01;
			opacitySlider.value = 1;
		}

		private function startBtnClickHD(e:MouseEvent):void
		{
			var i:int;
			var ball:Circle;
			var tween:OreOreTween;
			if (ore == null) {
				var duration:Number = durationSlider.value;
				var easing:String = String(easingList.selectedItem);

				balls = [];
				tweens = [];

				for (i = 0; i < ballNum; i++) {
					ball = new Circle(3, 0xffffff * Math.random());
					addChild(ball);
					//初期位置へ
					var offset:Array = getRandomOffSet();
					ball.setPosition(startPos.x + offset[0], startPos.y + offset[1]);
					ball.alpha = 1;
					balls.push(ball);

					//使い方
					ore = new OreOreTween(ball, {
						x:endPos.x,
						y:endPos.y,
						alpha:opacitySlider.value
						}, duration, easing);
					if (i == ballNum - 1) {
						ore.addEventListener(Event.COMPLETE, oreCompleteHD);
					}
					ore.start();
					tweens.push(ore);
				}

				startBtn.label = "PAUSE";
			}else if (ore.isTweening) {
				for (i = 0; i < ballNum; i++) {
					tween = tweens[i];
					tween.pause();
				}
//				ore.pause();
				startBtn.label = "RESUME";
			}else if (!ore.isTweening) {
				for (i = 0; i < ballNum; i++) {
					tween = tweens[i];
					tween.resume();
				}
//				ore.resume();
				startBtn.label = "PAUSE";
			}
		}

		private function getRandomOffSet():Array
		{
			var rad:Number = Math.PI * 2 * Math.random();
			var radius:Number = 100 * Math.random();
			return [Math.cos(rad) * radius, Math.sin(rad) * radius];
		}

		private function oreCompleteHD(e:Event):void
		{
			ore.removeEventListener(Event.COMPLETE, oreCompleteHD);
			ore = null;
			var i:int;
			var ball:Circle;
			for (i = 0; i < ballNum; i++) {
				ball = balls[i];
				removeChild(ball);
				ball = null;
			}
			startBtn.label = "START";
		}

		private function getEasingListItem():Array
		{
			var ar:Array = [
			"easeNone",
			"easeInQuad",
			"easeOutQuad",
			"easeInOutQuad",
			"easeOutInQuad",
			"easeInCubic",
			"easeOutCubic",
			"easeInOutCubic",
			"easeOutInCubic",
			"easeInQuart",
			"easeOutQuart",
			"easeInOutQuart",
			"easeOutInQuart",
			"easeInQuint",
			"easeOutQuint",
			"easeInOutQuint",
			"easeOutInQuint",
			"easeInSine",
			"easeOutSine",
			"easeInOutSine",
			"easeOutInSine",
			"easeInExpo",
			"easeOutExpo",
			"easeInOutExpo",
			"easeOutInExpo",
			"easeInCirc",
			"easeOutCirc",
			"easeInOutCirc",
			"easeOutInCirc",
			"easeInElastic",
			"easeOutElastic",
			"easeInOutElastic",
			"easeOutInElastic",
			"easeInBack",
			"easeOutBack",
			"easeInOutBack",
			"easeOutInBack",
			"easeInBounce",
			"easeOutBounce",
			"easeInOutBounce",
			"easeOutInBounce"
			];
			return ar;
		}
	}

}

他のクラスは前回と同じなんで割愛します。
ソースコード一式をアップしましたので、興味があったら見てください。

作ってみての感想とか

とりあえず、今回で俺俺Tweenは完了とします。
あとは、フィルター処理やそれぞれの個性となるような機能を追加していってみたら面白いかもしれないです。

今回のOreOreTweenだけであれば、

・OreOreTween（Tweenのメインクラス）
・Equations（イージング）
・UpdateManager（最適化用のEnterframeをひきうけるユーティリティ）

の３つのクラスだけでできることがわかりました。
意外と少ない要素でできるんだなーと。
なんで、Tweenライブラリのクラス数が多いものは、基本部分ではなくそれぞれの独自機能に
多くの容量を割いているのではないかと思いました。
また、今回作ったものは1000個のSpriteでフレームレートがさがってきているので、
このあたりの最適化もいろいろと工夫されているんじゃないかと思いました。

さて、OreOreTweenです。
今回は複数プロパティの対応と、終了イベントの発行に対応します。

今回作ったものです。
赤い丸はドラッグすることができます。
新たにOPACITY（透明度）のスライダもつけてみました。
ポーズと、レジュームにも対応しました。

実は、前回でTweenエンジンは既に完成しているので、残作業をちまちまやっていくだけです。
前回までは、x座標しかTweenすることができなかったので、y座標とか、alphaとかそういうのに対応しましょうという感じです。
そんで、使うときのコードはこんな感じにしました。

			//使い方
			var ore:OreOreTween = new OreOreTween(ball, {
				x:endPos.x,
				y:endPos.y,
				alpha:opacitySlider.value
				}, duration, easing);
			ore.addEventListener(Event.COMPLETE, oreCompleteHD);
			ore.start();

クラスの変更点としては、
・イベントの発行（dispatchEvent）ができるようにEventDispatcherのサブクラスとする
・Event.ENTER_FRAMEがEventDispatcherだと作動しなかったので仕方なくSpriteにした
・Mainでおこなっていた、ターゲットへのプロパティの適用をOreOreTweenでもつようにする
・start,pause,resumeのメソッド追加

という感じでしょうか。
自分で作ってみて驚いたのですが、イージングの定数部分をぬかした基本的なプログラム部分の行数は意外と短いです。

このままだと、インスタンスを生成するごとにEvent.ENTER_FRAMEを呼び出しちゃっているので、次回はそれをまとめるクラスを作ってみようと思います。
あと、delayの実装もしてなかったので、その辺もかな。

以下ソースです。

■OreOreTween

package  kuma_de
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.EventDispatcher;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OreOreTween extends Sprite
	{
		//easing
		public static const EASE_NONE:String = "easeNone";
		public static const EASE_IN_QUAD:String = "easeInQuad";
		public static const EASE_OUT_QUAD:String = "easeOutQuad";
		public static const EASE_IN_OUT_QUAD:String = "easeInOutQuad";
		public static const EASE_OUT_IN_QUAD:String = "easeOutInQuad";
		public static const EASE_IN_CUBIC:String = "easeInCubic";
		public static const EASE_OUT_CUBIC:String = "easeOutCubic";
		public static const EASE_IN_OUT_CUBIC:String = "easeInOutCubic";
		public static const EASE_OUT_IN_CUBIC:String = "easeOutInCubic";
		public static const EASE_IN_QUART:String = "easeInQuart";
		public static const EASE_OUT_QUART:String = "easeOutQuart";
		public static const EASE_IN_OUT_QUART:String = "easeInOutQuart";
		public static const EASE_OUT_IN_QUART:String = "easeOutInQuart";
		public static const EASE_IN_QUINT:String = "easeInQuint";
		public static const EASE_OUT_QUINT:String = "easeOutQuint";
		public static const EASE_IN_OUT_QUINT:String = "easeInOutQuint";
		public static const EASE_OUT_IN_QUINT:String = "easeOutInQuint";
		public static const EASE_IN_SINE:String = "easeInSine";
		public static const EASE_OUT_SINE:String = "easeOutSine";
		public static const EASE_IN_OUT_SINE:String = "easeInOutSine";
		public static const EASE_OUT_IN_SINE:String = "easeOutInSine";
		public static const EASE_IN_EXPO:String = "easeInExpo";
		public static const EASE_OUT_EXPO:String = "easeOutExpo";
		public static const EASE_IN_OUT_EXPO:String = "easeInOutExpo";
		public static const EASE_OUT_IN_EXPO:String = "easeOutInExpo";
		public static const EASE_IN_CIRC:String = "easeInCirc";
		public static const EASE_OUT_CIRC:String = "easeOutCirc";
		public static const EASE_IN_OUT_CIRC:String = "easeInOutCirc";
		public static const EASE_OUT_IN_CIRC:String = "easeOutInCirc";
		public static const EASE_IN_ELASTIC:String = "easeInElastic";
		public static const EASE_OUT_ELASTIC:String = "easeOutElastic";
		public static const EASE_IN_OUT_ELASTIC:String = "easeInOutElastic";
		public static const EASE_OUT_IN_ELASTIC:String = "easeOutInElastic";
		public static const EASE_IN_BACK:String = "easeInBack";
		public static const EASE_OUT_BACK:String = "easeOutBack";
		public static const EASE_IN_OUT_BACK:String = "easeInOutBack";
		public static const EASE_OUT_IN_BACK:String = "easeOutInBack";
		public static const EASE_IN_BOUNCE:String = "easeInBounce";
		public static const EASE_OUT_BOUNCE:String = "easeOutBounce";
		public static const EASE_IN_OUT_BOUNCE:String = "easeInOutBounce";
		public static const EASE_OUT_IN_BOUNCE:String = "easeOutInBounce";

		private var _target:*;
		private var _tweenObjects:Object;
		private var _updateCount:int;
		private var _maxUpdateCount:int;
		private var _isTweening:Boolean;
		public function get isTweening():Boolean
		{
			return _isTweening;
		}

		public static function getTweenValues(to:Number, from:Number, duration:Number = 1.0, easing:String = EASE_NONE):Array
		{
			var frameRate:int = 30;//フレームレート

			var values:Array = [];
			var segmentNum:int = Math.floor(frameRate * duration); //分割数

			var i:int;
			var t:Number;
			var dt:Number = 1 / segmentNum;
			var time:Number;
			var value:Number;
			for (i = 0; i <= segmentNum; i++) {
				t = dt * i; //tは0以上1以下の範囲で動く
				time = t * duration; //開始からの時刻（秒）

				value = Equations[easing](time, from, to - from, duration);
				values.push(value);
			}
			return values;
		}

		public function OreOreTween(target:*, to:Object, duration:Number = 1.0, easing:String = EASE_NONE, delay:Number = 0)
		{
			_isTweening = false;
			_tweenObjects = { };
			_target = target;

			for (var i:String in to) {
				_tweenObjects[i] = getTweenValues(to[i], target[i], duration, easing);
				_maxUpdateCount = _tweenObjects[i].length;
			}
		}

		public function start():void
		{
			if (!_isTweening)
			{
				_isTweening = true;
				_updateCount = 0;
				addEventListener(Event.ENTER_FRAME, update);
			}
		}

		public function pause():void
		{
			if (_isTweening)
			{
				removeEventListener(Event.ENTER_FRAME, update);
				_isTweening = false;
			}
		}

		public function reset():void
		{
			_updateCount = 0;
		}

		public function resume():void
		{
			if (!_isTweening)
			{
				addEventListener(Event.ENTER_FRAME, update);
				_isTweening = true;
			}
		}

		private function update(e:Event):void
		{
			//tween終了
			if (_updateCount == _maxUpdateCount)
			{
				pause();
				dispatchEvent(new Event(Event.COMPLETE));

			//tween値を適用
			}else {
				var tweenValues:Array;
				var value:Number;
				for (var i:String in _tweenObjects) {
					_target[i] = _tweenObjects[i][_updateCount];
				}
				_updateCount++;
			}
		}
	}
}

■Main

package
{
	import com.bit101.components.HSlider;
	import com.bit101.components.Label;
	import com.bit101.components.List;
	import com.bit101.components.PushButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import kuma_de.OreOreTween;

	/**
	 * ...
	 * @author KinkumaDesign
	 */
	[SWF(width="450",height="450",backgroundColor="0x000000",frameRate="30")]
	public class Main extends Sprite
	{
		public var ball:Circle;
		public var startPos:Circle;
		public var endPos:Circle;
		public var startBtn:PushButton;
		public var easingList:List;
		public var durationSlider:HSlider;
		public var opacitySlider:HSlider;

		public var ore:OreOreTween;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);

			ball = new Circle(20, 0x1ECAE8);
			addChild(ball);
			ball.setPosition(50, 100);

			startPos = new Circle(10, 0xE91283, 1, true);
			addChild(startPos);
			startPos.setPosition(50, 100);

			endPos = new Circle(10, 0xE91283, 1, true);
			addChild(endPos);
			endPos.setPosition(400, 200);

			startBtn = new PushButton(this, 250, 380, "start", startBtnClickHD);

			var label:Label = new Label(this, 100, 280, "EASING");
			label.textField.textColor = 0xffffff;
			var easingListItem:Array = getEasingListItem();
			easingList = new List(this, 100, 300, easingListItem);
			easingList.selectedIndex = 1;

			label = new Label(this, 250, 280, "DULATION");
			label.textField.textColor = 0xffffff;

			durationSlider = new HSlider(this, 250, 300, null);
			durationSlider.maximum = 2.0;
			durationSlider.minimum = 0.1;
			durationSlider.tick = 0.1;
			durationSlider.value = 1.1;

			label = new Label(this, 250, 320, "OPACITY");
			label.textField.textColor = 0xffffff;
			opacitySlider = new HSlider(this, 250, 340, null);
			opacitySlider.maximum = 1.0;
			opacitySlider.minimum = 0;
			opacitySlider.tick = 0.01;
			opacitySlider.value = 0;
		}

		private function startBtnClickHD(e:MouseEvent):void
		{
			if (ore == null) {
				//初期位置へ
				ball.setPosition(startPos.x, startPos.y);
				ball.alpha = 1;

				var duration:Number = durationSlider.value;
				var easing:String = String(easingList.selectedItem);

				//使い方
				ore = new OreOreTween(ball, {
					x:endPos.x,
					y:endPos.y,
					alpha:opacitySlider.value
					}, duration, easing);
				ore.addEventListener(Event.COMPLETE, oreCompleteHD);
				ore.start();

				startBtn.label = "PAUSE";
			}else if (ore.isTweening) {
				ore.pause();
				startBtn.label = "RESUME";
			}else if (!ore.isTweening) {
				ore.resume();
				startBtn.label = "PAUSE";
			}
		}

		private function oreCompleteHD(e:Event):void
		{
			ore.removeEventListener(Event.COMPLETE, oreCompleteHD);
			ore = null;
			startBtn.label = "START";
		}

		private function getEasingListItem():Array
		{
			var ar:Array = [
			"easeNone",
			"easeInQuad",
			"easeOutQuad",
			"easeInOutQuad",
			"easeOutInQuad",
			"easeInCubic",
			"easeOutCubic",
			"easeInOutCubic",
			"easeOutInCubic",
			"easeInQuart",
			"easeOutQuart",
			"easeInOutQuart",
			"easeOutInQuart",
			"easeInQuint",
			"easeOutQuint",
			"easeInOutQuint",
			"easeOutInQuint",
			"easeInSine",
			"easeOutSine",
			"easeInOutSine",
			"easeOutInSine",
			"easeInExpo",
			"easeOutExpo",
			"easeInOutExpo",
			"easeOutInExpo",
			"easeInCirc",
			"easeOutCirc",
			"easeInOutCirc",
			"easeOutInCirc",
			"easeInElastic",
			"easeOutElastic",
			"easeInOutElastic",
			"easeOutInElastic",
			"easeInBack",
			"easeOutBack",
			"easeInOutBack",
			"easeOutInBack",
			"easeInBounce",
			"easeOutBounce",
			"easeInOutBounce",
			"easeOutInBounce"
			];
			return ar;
		}
	}

}

■Circle

package
{
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Circle extends Sprite
	{
		public function Circle(radius:Number = 5, color:int = 0, alpha:Number = 1, draggable:Boolean = false)
		{
			var g:Graphics = this.graphics;
			g.beginFill(color, alpha);
			g.drawCircle(0, 0, radius);
			g.endFill();

			if (draggable)
			{
				addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHD);
				buttonMode = true;
			}
		}

		private function mouseDownHD(e:MouseEvent):void
		{
			if (stage != null)
			{
				stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHD);
				startDrag();
			}
		}

		private function mouseUpHD(e:MouseEvent):void
		{
			stage.removeEventListener(MouseEvent.MOUSE_UP, mouseUpHD);
			stopDrag();
		}

		public function setPosition(posX:Number, posY:Number):void
		{
			x = posX;
			y = posY;
		}
	}

}

■Equations

/*
Licensed under the MIT License

Copyright (c) 2006-2008 Zeh Fernando, Nate Chatellier, Arthur Debert and Francis
Turmel

Permission is hereby granted, free of charge, to any person obtaining a copy of
this software and associated documentation files (the "Software"), to deal in
the Software without restriction, including without limitation the rights to
use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
the Software, and to permit persons to whom the Software is furnished to do so,
subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

http://code.google.com/p/tweener/
http://code.google.com/p/tweener/wiki/License

-------------------------------------------------------------------------------------

Disclaimer for Robert Penner's Easing Equations license:

TERMS OF USE - EASING EQUATIONS

Open source under the BSD License.

Copyright © 2001 Robert Penner
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:

    * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
    * Neither the name of the author nor the names of contributors may be used to endorse or promote products derived from this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

package  kuma_de
{
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Equations
	{

	// ==================================================================================================================================
	// TWEENING EQUATIONS functions -----------------------------------------------------------------------------------------------------
	// (the original equations are Robert Penner's work as mentioned on the disclaimer)
	// (the original code is from Tweener)

	// ==================================================================================================================================
	// TWEENING EQUATIONS functions -----------------------------------------------------------------------------------------------------
	// (the original equations are Robert Penner's work as mentioned on the disclaimer)

		/**
		 * Easing equation function for a simple linear tweening, with no easing.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeNone (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*t/d + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing out: decelerating to zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c *(t/=d)*(t-2) + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing in/out: acceleration until halfway, then deceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return c/2*t*t + b;
			return -c/2 * ((--t)*(t-2) - 1) + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing out/in: deceleration until halfway, then acceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutQuad (t*2, b, c/2, d, p_params);
			return easeInQuad((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a cubic (t^3) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInCubic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t*t + b;
		}

		/**
		 * Easing equation function for a cubic (t^3) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutCubic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*((t=t/d-1)*t*t + 1) + b;
		}

		/**
		 * Easing equation function for a cubic (t^3) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutCubic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return c/2*t*t*t + b;
			return c/2*((t-=2)*t*t + 2) + b;
		}

		/**
		 * Easing equation function for a cubic (t^3) easing out/in: deceleration until halfway, then acceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInCubic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutCubic (t*2, b, c/2, d, p_params);
			return easeInCubic((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a quartic (t^4) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInQuart (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t*t*t + b;
		}

		/**
		 * Easing equation function for a quartic (t^4) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutQuart (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c * ((t=t/d-1)*t*t*t - 1) + b;
		}

		/**
		 * Easing equation function for a quartic (t^4) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutQuart (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return c/2*t*t*t*t + b;
			return -c/2 * ((t-=2)*t*t*t - 2) + b;
		}

		/**
		 * Easing equation function for a quartic (t^4) easing out/in: deceleration until halfway, then acceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInQuart (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutQuart (t*2, b, c/2, d, p_params);
			return easeInQuart((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a quintic (t^5) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInQuint (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t*t*t*t + b;
		}

		/**
		 * Easing equation function for a quintic (t^5) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutQuint (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*((t=t/d-1)*t*t*t*t + 1) + b;
		}

		/**
		 * Easing equation function for a quintic (t^5) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutQuint (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return c/2*t*t*t*t*t + b;
			return c/2*((t-=2)*t*t*t*t + 2) + b;
		}

		/**
		 * Easing equation function for a quintic (t^5) easing out/in: deceleration until halfway, then acceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInQuint (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutQuint (t*2, b, c/2, d, p_params);
			return easeInQuint((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a sinusoidal (sin(t)) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInSine (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c * Math.cos(t/d * (Math.PI/2)) + c + b;
		}

		/**
		 * Easing equation function for a sinusoidal (sin(t)) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutSine (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c * Math.sin(t/d * (Math.PI/2)) + b;
		}

		/**
		 * Easing equation function for a sinusoidal (sin(t)) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutSine (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c/2 * (Math.cos(Math.PI*t/d) - 1) + b;
		}

		/**
		 * Easing equation function for a sinusoidal (sin(t)) easing out/in: deceleration until halfway, then acceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInSine (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutSine (t*2, b, c/2, d, p_params);
			return easeInSine((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for an exponential (2^t) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInExpo (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return (t==0) ? b : c * Math.pow(2, 10 * (t/d - 1)) + b - c * 0.001;
		}

		/**
		 * Easing equation function for an exponential (2^t) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutExpo (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return (t==d) ? b+c : c * 1.001 * (-Math.pow(2, -10 * t/d) + 1) + b;
		}

		/**
		 * Easing equation function for an exponential (2^t) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutExpo (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t==0) return b;
			if (t==d) return b+c;
			if ((t/=d/2) < 1) return c/2 * Math.pow(2, 10 * (t - 1)) + b - c * 0.0005;
			return c/2 * 1.0005 * (-Math.pow(2, -10 * --t) + 2) + b;
		}

		/**
		 * Easing equation function for an exponential (2^t) easing out/in: deceleration until halfway, then acceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInExpo (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutExpo (t*2, b, c/2, d, p_params);
			return easeInExpo((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a circular (sqrt(1-t^2)) easing in: accelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInCirc (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c * (Math.sqrt(1 - (t/=d)*t) - 1) + b;
		}

		/**
		 * Easing equation function for a circular (sqrt(1-t^2)) easing out: decelerating from zero velocity.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutCirc (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c * Math.sqrt(1 - (t=t/d-1)*t) + b;
		}

		/**
		 * Easing equation function for a circular (sqrt(1-t^2)) easing in/out: acceleration until halfway, then deceleration.
 		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutCirc (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return -c/2 * (Math.sqrt(1 - t*t) - 1) + b;
			return c/2 * (Math.sqrt(1 - (t-=2)*t) + 1) + b;
		}

		/**
		 * Easing equation function for a circular (sqrt(1-t^2)) easing out/in: deceleration until halfway, then acceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInCirc (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutCirc (t*2, b, c/2, d, p_params);
			return easeInCirc((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for an elastic (exponentially decaying sine wave) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param a		Amplitude.
		 * @param p		Period.
		 * @return		The correct value.
		 */
		public static function easeInElastic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t==0) return b;
			if ((t/=d)==1) return b+c;
			var p:Number = !Boolean(p_params) || isNaN(p_params.period) ? d*.3 : p_params.period;
			var s:Number;
			var a:Number = !Boolean(p_params) || isNaN(p_params.amplitude) ? 0 : p_params.amplitude;
			if (!Boolean(a) || a < Math.abs(c)) {
				a = c;
				s = p/4;
			} else {
				s = p/(2*Math.PI) * Math.asin (c/a);
			}
			return -(a*Math.pow(2,10*(t-=1)) * Math.sin( (t*d-s)*(2*Math.PI)/p )) + b;
		}

		/**
		 * Easing equation function for an elastic (exponentially decaying sine wave) easing out: decelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param a		Amplitude.
		 * @param p		Period.
		 * @return		The correct value.
		 */
		public static function easeOutElastic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t==0) return b;
			if ((t/=d)==1) return b+c;
			var p:Number = !Boolean(p_params) || isNaN(p_params.period) ? d*.3 : p_params.period;
			var s:Number;
			var a:Number = !Boolean(p_params) || isNaN(p_params.amplitude) ? 0 : p_params.amplitude;
			if (!Boolean(a) || a < Math.abs(c)) {
				a = c;
				s = p/4;
			} else {
				s = p/(2*Math.PI) * Math.asin (c/a);
			}
			return (a*Math.pow(2,-10*t) * Math.sin( (t*d-s)*(2*Math.PI)/p ) + c + b);
		}

		/**
		 * Easing equation function for an elastic (exponentially decaying sine wave) easing in/out: acceleration until halfway, then deceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param a		Amplitude.
		 * @param p		Period.
		 * @return		The correct value.
		 */
		public static function easeInOutElastic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t==0) return b;
			if ((t/=d/2)==2) return b+c;
			var p:Number = !Boolean(p_params) || isNaN(p_params.period) ? d*(.3*1.5) : p_params.period;
			var s:Number;
			var a:Number = !Boolean(p_params) || isNaN(p_params.amplitude) ? 0 : p_params.amplitude;
			if (!Boolean(a) || a < Math.abs(c)) {
				a = c;
				s = p/4;
			} else {
				s = p/(2*Math.PI) * Math.asin (c/a);
			}
			if (t < 1) return -.5*(a*Math.pow(2,10*(t-=1)) * Math.sin( (t*d-s)*(2*Math.PI)/p )) + b;
			return a*Math.pow(2,-10*(t-=1)) * Math.sin( (t*d-s)*(2*Math.PI)/p )*.5 + c + b;
		}

		/**
		 * Easing equation function for an elastic (exponentially decaying sine wave) easing out/in: deceleration until halfway, then acceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param a		Amplitude.
		 * @param p		Period.
		 * @return		The correct value.
		 */
		public static function easeOutInElastic (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutElastic (t*2, b, c/2, d, p_params);
			return easeInElastic((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a back (overshooting cubic easing: (s+1)*t^3 - s*t^2) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param s		Overshoot ammount: higher s means greater overshoot (0 produces cubic easing with no overshoot, and the default value of 1.70158 produces an overshoot of 10 percent).
		 * @return		The correct value.
		 */
		public static function easeInBack (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			var s:Number = !Boolean(p_params) || isNaN(p_params.overshoot) ? 1.70158 : p_params.overshoot;
			return c*(t/=d)*t*((s+1)*t - s) + b;
		}

		/**
		 * Easing equation function for a back (overshooting cubic easing: (s+1)*t^3 - s*t^2) easing out: decelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param s		Overshoot ammount: higher s means greater overshoot (0 produces cubic easing with no overshoot, and the default value of 1.70158 produces an overshoot of 10 percent).
		 * @return		The correct value.
		 */
		public static function easeOutBack (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			var s:Number = !Boolean(p_params) || isNaN(p_params.overshoot) ? 1.70158 : p_params.overshoot;
			return c*((t=t/d-1)*t*((s+1)*t + s) + 1) + b;
		}

		/**
		 * Easing equation function for a back (overshooting cubic easing: (s+1)*t^3 - s*t^2) easing in/out: acceleration until halfway, then deceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param s		Overshoot ammount: higher s means greater overshoot (0 produces cubic easing with no overshoot, and the default value of 1.70158 produces an overshoot of 10 percent).
		 * @return		The correct value.
		 */
		public static function easeInOutBack (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			var s:Number = !Boolean(p_params) || isNaN(p_params.overshoot) ? 1.70158 : p_params.overshoot;
			if ((t/=d/2) < 1) return c/2*(t*t*(((s*=(1.525))+1)*t - s)) + b;
			return c/2*((t-=2)*t*(((s*=(1.525))+1)*t + s) + 2) + b;
		}

		/**
		 * Easing equation function for a back (overshooting cubic easing: (s+1)*t^3 - s*t^2) easing out/in: deceleration until halfway, then acceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @param s		Overshoot ammount: higher s means greater overshoot (0 produces cubic easing with no overshoot, and the default value of 1.70158 produces an overshoot of 10 percent).
		 * @return		The correct value.
		 */
		public static function easeOutInBack (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutBack (t*2, b, c/2, d, p_params);
			return easeInBack((t*2)-d, b+c/2, c/2, d, p_params);
		}

		/**
		 * Easing equation function for a bounce (exponentially decaying parabolic bounce) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInBounce (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c - easeOutBounce (d-t, 0, c, d) + b;
		}

		/**
		 * Easing equation function for a bounce (exponentially decaying parabolic bounce) easing out: decelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutBounce (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d) < (1/2.75)) {
				return c*(7.5625*t*t) + b;
			} else if (t < (2/2.75)) {
				return c*(7.5625*(t-=(1.5/2.75))*t + .75) + b;
			} else if (t < (2.5/2.75)) {
				return c*(7.5625*(t-=(2.25/2.75))*t + .9375) + b;
			} else {
				return c*(7.5625*(t-=(2.625/2.75))*t + .984375) + b;
			}
		}

		/**
		 * Easing equation function for a bounce (exponentially decaying parabolic bounce) easing in/out: acceleration until halfway, then deceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutBounce (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeInBounce (t*2, 0, c, d) * .5 + b;
			else return easeOutBounce (t*2-d, 0, c, d) * .5 + c*.5 + b;
		}

		/**
		 * Easing equation function for a bounce (exponentially decaying parabolic bounce) easing out/in: deceleration until halfway, then acceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutInBounce (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if (t < d/2) return easeOutBounce (t*2, b, c/2, d, p_params);
			return easeInBounce((t*2)-d, b+c/2, c/2, d, p_params);
		}
	}

}

さて、俺俺Tweenです。
今回つくったもの。なんかTweenエンジンっぽくなってきました。
時間設定（duration）とイージング設定（easing）をつけてみました。

イージングってなによ

前回つくったものは、始点と終点を等分割して、各地点を計算しました。
今回は点をかたよらせることによって、最初ゆっくり、あとで速くみたいに動きに変化をつけてみましょう。

さて、始点と終点から、どうやってかたよった点を取得するかですが、
ロバート　パナーさんのイージングの式を利用させていただきます。

>> Robert Penner’s Easing Equations

この式はTweenerをはじめとした各種Tweenライブラリでも使用されています。
例えばeaseInQuadという式であれば、

		/**
		 * Easing equation function for a quadratic (t^2) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds). 　値を取得したい時間（イージングを開始してからの時間）
		 * @param b		Starting value.　開始時点の値
		 * @param c		Change needed in value.　変化値（開始が10で終了が100なら90）
		 * @param d		Expected easing duration (in frames or seconds).　イージング時間
		 * @return		The correct value.
		 */
		public static function easeInQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t + b;
		}

こんな感じの式であらわすことができます。
このとき、引数b,c,dは１回のTweenでは固定なので、時間tを変化させて、そのときの値を取得していきます。
そうすると、偏った各地点のイージング値を取得することができます。
あとは、それを決まったタイミングで（EnterframeかTimerで）表示オブジェクトに適用してあげればいいです。

時間指定

Tween時間を変更できるようにしましょう。
今回のTweenエンジンはTimerベースではなく、Enterframeベースのものとします。
全部の分割数はフレームレート30のとき、

var segmentNum:int = Math.floor(frameRate * duration);

であらわすことができます。
これとさきほどのイージングの式を使えば、今回のデモが完成します。

今回のソースです。

■Main

package
{
	import com.bit101.components.HSlider;
	import com.bit101.components.Label;
	import com.bit101.components.List;
	import com.bit101.components.PushButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;

	/**
	 * ...
	 * @author KinkumaDesign
	 */
	[SWF(width="450",height="450",backgroundColor="0x000000",frameRate="30")]
	public class Main extends Sprite
	{
		public var ball:Circle;
		public var startBtn:PushButton;
		public var easingList:List;
		public var durationSlider:HSlider;

		public const START_POS:Point = new Point(50, 150);//開始地点
		public const END_POS:Point = new Point(400, 150);//終了地点

		public var tweenValues:Array;
		public var tweenCount:int;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);

			ball = new Circle(20, 0x1ECAE8);
			addChild(ball);
			ball.setPosition(START_POS.x, START_POS.y);

			startBtn = new PushButton(this, 250, 380, "start", startBtnClickHD);

			var label:Label = new Label(this, 100, 280, "EASING");
			label.textField.textColor = 0xffffff;
			var easingListItem:Array = ["easeNone", "easeInQuad", "easeOutQuad", "easeInOutQuad"];
			easingList = new List(this, 100, 300, easingListItem);
			easingList.selectedIndex = 1;

			label = new Label(this, 250, 280, "DULATION");
			label.textField.textColor = 0xffffff;

			durationSlider = new HSlider(this, 250, 300, null);
			durationSlider.maximum = 2.0;
			durationSlider.minimum = 0.1;
			durationSlider.tick = 0.1;
			durationSlider.value = 1.1;
		}

		private function startBtnClickHD(e:MouseEvent):void
		{
			var duration:Number = durationSlider.value;
			var easing:String = String(easingList.selectedItem);

			tweenValues = OreOreTween.getTweenValues(END_POS.x, START_POS.x, duration, easing);
			trace(tweenValues); //各地点

			//tweenスタート
			startBtn.visible = false;
			tweenCount = 0;
			addEventListener(Event.ENTER_FRAME, updateTween);
		}

		private function updateTween(e:Event):void
		{

			//tween終了
			if (tweenCount == tweenValues.length)
			{
				removeEventListener(Event.ENTER_FRAME, updateTween);
				startBtn.visible = true;
			//tween値を適用
			}else {
				var value:Number = tweenValues[tweenCount];
				ball.x = value;
				tweenCount++;
			}
		}

	}

}

■OreOreTween

package
{
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OreOreTween
	{
		public static const EASE_NONE:String = "easeNone";
		public static const EASE_IN_QUAD:String = "easeInQuad";
		public static const EASE_OUT_QUAD:String = "easeOutQuad";
		public static const EASE_IN_OUT_QUAD:String = "easeInOutQuad";

		public static function getTweenValues(to:Number, from:Number, duration:Number = 1.0, easing:String = EASE_NONE):Array
		{
			var frameRate:int = 30;//フレームレート

			var values:Array = [];
			var segmentNum:int = Math.floor(frameRate * duration); //分割数

			var i:int;
			var t:Number;
			var dt:Number = 1 / segmentNum;
			var time:Number;
			var value:Number;
			for (i = 0; i <= segmentNum; i++) {
				t = dt * i; //tは0以上1以下の範囲で動く
				time = t * duration; //開始からの時刻（秒）

				//easingによる分岐
				switch(easing) {
					case EASE_NONE:
						value = OreOreTweenEquations.easeNone(time, from, to - from, duration);
					break;
					case EASE_IN_QUAD:
						value = OreOreTweenEquations.easeInQuad(time, from, to - from, duration);
					break;
					case EASE_OUT_QUAD:
						value = OreOreTweenEquations.easeOutQuad(time, from, to - from, duration);
					break;
					case EASE_IN_OUT_QUAD:
						value = OreOreTweenEquations.easeInOutQuad(time, from, to - from, duration);
					break;
				}
				values.push(value);
			}
			return values;
		}

	}
}

■OreOreTweenEquations
今回はTweenerからソースをもってきているので、Tweenerのライセンスもつけています。

/*
Licensed under the MIT License

Copyright (c) 2006-2008 Zeh Fernando, Nate Chatellier, Arthur Debert and Francis
Turmel

Permission is hereby granted, free of charge, to any person obtaining a copy of
this software and associated documentation files (the "Software"), to deal in
the Software without restriction, including without limitation the rights to
use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
the Software, and to permit persons to whom the Software is furnished to do so,
subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

http://code.google.com/p/tweener/
http://code.google.com/p/tweener/wiki/License

-------------------------------------------------------------------------------------

Disclaimer for Robert Penner's Easing Equations license:

TERMS OF USE - EASING EQUATIONS

Open source under the BSD License.

Copyright © 2001 Robert Penner
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:

    * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
    * Neither the name of the author nor the names of contributors may be used to endorse or promote products derived from this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

package
{
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OreOreTweenEquations
	{

	// ==================================================================================================================================
	// TWEENING EQUATIONS functions -----------------------------------------------------------------------------------------------------
	// (the original equations are Robert Penner's work as mentioned on the disclaimer)
	// (the original code is from Tweener)

		/**
		 * Easing equation function for a simple linear tweening, with no easing.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeNone (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*t/d + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing in: accelerating from zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return c*(t/=d)*t + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing out: decelerating to zero velocity.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeOutQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			return -c *(t/=d)*(t-2) + b;
		}

		/**
		 * Easing equation function for a quadratic (t^2) easing in/out: acceleration until halfway, then deceleration.
		 *
		 * @param t		Current time (in frames or seconds).
		 * @param b		Starting value.
		 * @param c		Change needed in value.
		 * @param d		Expected easing duration (in frames or seconds).
		 * @return		The correct value.
		 */
		public static function easeInOutQuad (t:Number, b:Number, c:Number, d:Number, p_params:Object = null):Number {
			if ((t/=d/2) < 1) return c/2*t*t + b;
			return -c/2 * ((--t)*(t-2) - 1) + b;
		}
	}

}

■Circle

package
{
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.geom.Point;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Circle extends Sprite
	{

		public function Circle(radius:Number = 5, color:int = 0, alpha:Number = 1)
		{
			var g:Graphics = this.graphics;
			g.beginFill(color, alpha);
			g.drawCircle(0, 0, radius);
			g.endFill();
		}

		public function setPosition(posX:Number, posY:Number):void
		{
			x = posX;
			y = posY;
		}
	}

}

ご報告なのですが、先月のこのサイトのページビューがついに93000[ページ/月]になりました！
一度もはてブにホットエントリすることもなく、地味な記事ばかりなのですが、
9万越えを達成したのも、ひとえに皆様のおかげです。ありがとうございます！
次の目標は大台の10万ページビューです。がんばります。

近況です。
この間からようやく本腰いれてObjective-CというかiPhone/iPadアプリ開発もやりはじめまして。
なんとかいろいろとわかってきました。
役立ち情報などをもう少しためてから、ブログに書いていきたいと思います。

さて、本題です。今回から何度かにわたって俺俺Tweenエンジンを作っていきたいと思います。
ちまたにはTweenerやBetweenAS3、Tweensy、kTweenなどすばらしいTweenエンジンが
あるんですが、そこまで及ばなくても100コぐらいのTweenなら大丈夫！ぐらいのゆるいエンジンを
作りたいと思います。

今回つくったもの

Tweenエンジンって結局何

時間のあるかたはとりあえず、城戸さんの講義がわかりやすいと思います。

GEEKs in OSAKA
Flash モーションプログラミング + 大阪てら子

自分の理解としては、「Tweenエンジンは、始点と終点の値を分割したもの」だと思いました。

例えば、始点0、終点100の値をTweenするとします。
分割数を10としたとき、0,10,20,30,40,50,60,70,80,90,100となり、
分割数が5であれば、0,20,40,60,80,100となります。

それで、これらの分割した値を使って、タイマーやEnterframeの中でSpriteやMovieClipに
都度適用していくことで、パラパラアニメのように動いているように見える。というわけです。

城戸さんの講義ではパラメータtを使って、分割していました。
tは0 <= t <= 1 の範囲で動くパラメータです。

dtという値を考えます。
dtは分割数に応じて変化する値で、分割数が10なら 1 / 10 = 0.1、分割数が5なら 1 / 5 = 0.2となります。

さきほどの0から100までをtを使って分割すると
iを0から分割数までの変数として、tに応じた値valueはこんな感じになります。

t = dt * i;
value = (100 - 0) * t + 0;

valueの最後に0をたしているのは初期値が例えば20のときには

value = (100 - 20) * t + 20;

となるためです。
そんで、一番上に作ったデモの場合にあてはめると（実際のコードでは分割数を30にしてますが、図のために5にしてます）
こんな感じになります。

今回のコード

■Main

package
{
	import com.bit101.components.PushButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;

	/**
	 * ...
	 * @author KinkumaDesign
	 */
	[SWF(width="450",height="450",backgroundColor="0x000000",frameRate="30")]
	public class Main extends Sprite
	{
		public var ball:Circle;
		public var startBtn:PushButton;

		public const START_POS:Point = new Point(50, 150);//開始地点
		public const END_POS:Point = new Point(400, 150);//終了地点

		public var tweenValues:Array;
		public var tweenCount:int;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);

			ball = new Circle(20, 0x1ECAE8);
			addChild(ball);
			ball.setPosition(START_POS.x, START_POS.y);

			startBtn = new PushButton(this, 180, 330, "start", startBtnClickHD);
		}

		private function startBtnClickHD(e:MouseEvent):void
		{
			tweenValues = OreOreTween.getTweenValues(END_POS.x, START_POS.x);
			trace(tweenValues); //各地点

			//tweenスタート
			startBtn.visible = false;
			tweenCount = 0;
			addEventListener(Event.ENTER_FRAME, updateTween);
		}

		private function updateTween(e:Event):void
		{
			//tween終了
			if (tweenCount == tweenValues.length)
			{
				removeEventListener(Event.ENTER_FRAME, updateTween);
				startBtn.visible = true;
			//tween値を適用
			}else {
				var value:Number = tweenValues[tweenCount];
				ball.x = value;
				tweenCount++;
			}
		}

	}

}

■OreOreTween

package
{
	import flash.geom.Point;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class OreOreTween
	{
		public static function getTweenValues(to:Number, from:Number):Array
		{
			var values:Array = [];

			var segmentNum:Number = 30; //分割数
			var i:int;
			var t:Number;
			var dt:Number = 1 / segmentNum; //分割数
			var value:Number;
			for (i = 0; i <= segmentNum; i++) {
				t = dt * i; //tは0以上1以下の範囲で動く
				value = (to - from) * t + from;
				values.push(value);
			}
			return values;
		}
	}
}

■Circle

package
{
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.geom.Point;
	/**
	 * ...
	 * @author KinkumaDesign
	 */
	public class Circle extends Sprite
	{

		public function Circle(radius:Number = 5, color:int = 0, alpha:Number = 1)
		{
			var g:Graphics = this.graphics;
			g.beginFill(color, alpha);
			g.drawCircle(0, 0, radius);
			g.endFill();
		}

		public function setPosition(posX:Number, posY:Number):void
		{
			x = posX;
			y = posY;
		}
	}

}